#
# Permission is hereby granted, free of charge, to any person obtaining
# a copy of this software and associated documentation files (the
# "Software"), to deal in the Software without restriction, including
# without limitation the rights to use, copy, modify, merge, publish,
# distribute, sublicense, and/or sell copies of the Software, and to
# permit persons to whom the Software is furnished to do so, subject to
# the following conditions:
#
# The above copyright notice and this permission notice shall be
# included in all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
# EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
# MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
# NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
# LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
# OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
# WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

#
# Required preamble
#

cmake_minimum_required(VERSION 3.10)

list(APPEND CMAKE_PREFIX_PATH $ENV{KIM_API_CMAKE_PREFIX_DIR})
find_package(KIM-API-ITEMS 2.2 REQUIRED CONFIG)
#if(NOT TARGET kim-api)
#  enable_testing()
#  project("${KIM_API_PROJECT_NAME}" VERSION "${KIM_API_VERSION}"
#    LANGUAGES CXX C Fortran)
#endif()

# End preamble

kim_api_items_setup_before_project(ITEM_TYPE "modelDriver")
project(QUIP__MD_915965102628_000 LANGUAGES CXX C Fortran)
kim_api_items_setup_after_project(ITEM_TYPE "modelDriver")

add_kim_api_model_driver_library(
  NAME                    ${PROJECT_NAME}
  CREATE_ROUTINE_NAME     "create"
  CREATE_ROUTINE_LANGUAGE "fortran"
  )

target_sources(${PROJECT_NAME} PRIVATE
  QUIP_model_driver.F90
  )

if (${CMAKE_Fortran_COMPILER_ID} STREQUAL "GNU" AND ${CMAKE_C_COMPILER_ID} STREQUAL "GNU")
    set (CMAKE_COMPILER_STR gfortran)
elseif (${CMAKE_Fortran_COMPILER_ID} STREQUAL "Intel" AND ${CMAKE_C_COMPILER_ID} STREQUAL "Intel")
    set (CMAKE_COMPILER_STR ifort_icc)
else()
    message (FATAL_ERROR "CMAKE_Fortran_COMPILER_ID ${CMAKE_Fortran_COMPILER_ID} and CMAKE_C_COMPILER_ID ${CMAKE_C_COMPILER_ID} not supported, only pure GNU or Intel")
endif()

if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    set (CMAKE_QUIP_ARCH linux_x86_64_${CMAKE_COMPILER_STR})
elseif (${CMAKE_SYSTEM_NAME} STREQUAL "Darwin")
    set (CMAKE_QUIP_ARCH darwin_x86_64_${CMAKE_COMPILER_STR})
else()
    message (FATAL_ERROR "CMAKE_SYSTEM_NAME ${CMAKE_SYSTEM_NAME} not supported, only Linux and Darwin for now")
endif()

set(QUIP_COMP_FLAGS "CC=${CMAKE_C_COMPILER} CPLUSPLUS=${CMAKE_CXX_COMPILER} F77=${CMAKE_Fortran_COMPILER} F90=${CMAKE_Fortran_COMPILER} F95=${CMAKE_Fortran_COMPILER} LINKER=${CMAKE_Fortran_COMPILER} FPP=\"${CMAKE_Fortran_COMPILER} -E -x f95-cpp-input -P\"")

include(ExternalProject)
ExternalProject_Add(QUIP_project
    URL file://${CMAKE_CURRENT_SOURCE_DIR}/QUIP.tar.bz2
    BUILD_IN_SOURCE 1
    CONFIGURE_COMMAND bash -c "mkdir -p ./build/${CMAKE_QUIP_ARCH} && cp ${CMAKE_CURRENT_SOURCE_DIR}/Makefile.inc.openkim ./build/${CMAKE_QUIP_ARCH}/Makefile.inc && yes | sed 's/y//' | QUIP_ARCH=${CMAKE_QUIP_ARCH} make ${QUIP_COMP_FLAGS} config"
    BUILD_COMMAND bash -c "QUIP_ARCH=${CMAKE_QUIP_ARCH} make -j1 ${QUIP_COMP_FLAGS} PROGRAMS='' libquip.a"
    INSTALL_COMMAND ""
)

add_library(quip STATIC IMPORTED)
add_dependencies(quip QUIP_project)
set_target_properties(quip PROPERTIES IMPORTED_LOCATION ${CMAKE_CURRENT_BINARY_DIR}/QUIP_project-prefix/src/QUIP_project/build/${CMAKE_QUIP_ARCH}/libquip.a)
target_include_directories(${PROJECT_NAME} PUBLIC  ${CMAKE_CURRENT_BINARY_DIR}/QUIP_project-prefix/src/QUIP_project/build/${CMAKE_QUIP_ARCH})
target_link_libraries(${PROJECT_NAME} PUBLIC quip)

find_package(LAPACK REQUIRED)
target_link_libraries(${PROJECT_NAME} PUBLIC ${LAPACK_LIBRARIES})

set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -std=gnu")